Új hozzászólás Aktív témák
-
#3456
Fire/SOUL/CD
félisten
zseko
#3444
12 erdei köb fa felkuglizása és behordása után éreztem késztetést, hogy a rég elfeledett/megkopott -nagyon alap- batch programozási "tudásomat" felfrissítsem, amolyan "retro-feeling" kapcsán.
Szóval az alábbi "kódot" mentsd el tetszőleges névvel, de BAT kiterjesztéssel.@ECHO OFF
CLS
ECHO ╔═══════════════════════════════════════════════════╗
ECHO ║ Fire/SOUL/CD - 2022 ║
ECHO ╠═══════════════════════════════════════════════════╣
ECHO ║ A BATCH fájl a megadott mappában az adott fájlok ║
ECHO ║ nevével megegyező nevű mappákat hoz létre, majd ║
ECHO ║ átmozgatja a fájlokat a létrehozott mappákba. ║
ECHO ║ ║
ECHO ║ BATCH fájl [PARAMÉTER] ║
ECHO ║ PARAMÉTER: Elhagyható, ez esetben a BATCH fájlt ║
ECHO ║ tartalmazó mappában megy végbe a ║
ECHO ║ művelet. ║
ECHO ║ Megadható, ez esetben KÖTELEZŐEN ║
ECHO ║ MACSKAKÖRMÖK KÖZT kell szerepeltetni ║
ECHO ║ a mappa teljes útvonalát. ║
ECHO ║ ║
ECHO ║ Példa: BATCH fájl "d:\árvíztűrő tükörfúrógép" ║
ECHO ╚═══════════════════════════════════════════════════╝
ECHO:
ECHO BATCH fájl: "%~nx0"
IF NOT "%~1"=="" (
IF NOT EXIST "%~1" (
ECHO Paraméter: "%~1"
ECHO Műveleti mappa: Paraméter hibás, ilyen mappa nem létezik.
GOTO @EXIT
) ELSE (
ECHO Paraméter: "%~1"
CD /D "%~1"
)
) ELSE (
ECHO Paraméter: Nincs megadva
)
ECHO Műveleti mappa: "%CD%"
ECHO:
:@REPEATGETKEY
SET /P CONTINUEORNOT=Futtassam a műveletet? [I/N]
IF /I %CONTINUEORNOT%==N EXIT
IF /I NOT %CONTINUEORNOT%==I (
ECHO Nem megfelelő billentyű.
ECHO:
GOTO @REPEATGETKEY
)
ECHO:
SET FILECOUNTER=0
SET ERRORCOUNTER=0
SET BATCHFILENAME="%~nx0"
FOR %%a IN (*) DO (
IF NOT "%%a" == %BATCHFILENAME% (
ECHO Átmozgatandó fájl: "%%a"
ECHO Létrehozandó mappa: "%%~na"
IF NOT EXIST "%%~na" (
MD "%%~na"
MOVE "%%a" "%%~na"
SET /A FILECOUNTER=FILECOUNTER+1
) ELSE (
ECHO ╔══════════════════════════════════════════════════════════════════════════════════════╗
ECHO ║ HIBA: Mappát nem lehet létrehozni, mert ilyen névvel már létezik egy fájl, kihagyva. ║
ECHO ╚══════════════════════════════════════════════════════════════════════════════════════╝
SET /A ERRORCOUNTER=ERRORCOUNTER+1
)
ECHO:
)
)
ECHO ******************* EREDMÉNY *******************
ECHO Sikeresen átmozgatott fájl(ok): %FILECOUNTER% db.
ECHO Sikertelen művelet(ek): %ERRORCOUNTER% db.
:@EXIT
ECHO:
ECHO Program vége. Bármely billentyű leütésével kiléphetsz.
PAUSE>NUL1. Amennyiben nem akarsz belemódosítani, akkor nincs további teendőd
2. Ha bele szeretnél módosítani ÉS ékezetes betűket is használnál, akkor viszont a Windows beépített szövegszerkesztője alkalmatlan a feladatra. Ez esetben tedd ezt:
# töltsd el a Notepad++ aktuális verzióját (portable is lehet),
# nyisd meg a korábban tetszőleges néven elmentett BAT fájlt
# állítsd át a képen látható módon a karakterkódolás OEM 852-re, ekkor már tudsz ékezetes karaktereket is használni.FONTOS!
Ha ezt a kódot kimásolod és beilleszted egy üres BAT kiterjesztésű fájlba, akkor is "krix-krax-ok" lesznek, mert a webes kódolás "nem fér össze" a tradicionális DOS karakterkódolással Windows alatt. Ebben az esetben UTF-8-ra állítsd, így legalább a Notepad++ -ban jól jelenik meg, de futtatáskor akkor is "matyómintás" lesz...3. A BAT fájlt bemásolhatod abba a mappába, ahol futtatni szeretnéd, simán futtathatod vagy nem másolod be abba a mappába, hanem paraméterként megadott, hogy melyik mappán végezze el a műveletet
-
zseko
veterán
Az egyesével működőt végül sikerült megoldanom, még ha valószínűleg fapados módszerrel is
, mindenesetre működik, és már csak egy kattintás az eddigi minimum 8 mozdulat helyett. Így most alig egy-két perc volt a 150 file, a múltkori... inkább ki sem számolom mennyi idő helyett -
#2913
Fire/SOUL/CD
félisten
zseko
#2912
-
#2911
Fire/SOUL/CD
félisten
zseko
#2910
Több ablaknak sok értelme nem lenne, hisz pont ezért vannak a fülek...
Több fülön is lehet keresési eredményt betenni és azokat lehet a háttérben futtatva másolni, arról nem is beszélve, hogy elég részletesen lehet keresni is, ahhoz pl nem kell 2 fül meg 2 keresés, hogy pl a ZIP meg a PDF fájlokat listázd (pontosvesszővel kell elválasztani a fájlkiterjesztéseket a keresési mezőbe, ennél a példánál maradva *.pdf;*.zip )Ha rosszul értelmeztem a problémád, akkor sorry...
, mindenesetre működik, és már csak egy kattintás az eddigi minimum 8 mozdulat helyett. Így most alig egy-két perc volt a 150 file, a múltkori... inkább ki sem számolom mennyi idő helyett 
Új hozzászólás Aktív témák
- Xiaomi 15 256GB,Újszerű,Dobozával,12 hónap garanciával
- Samsung Galaxy S22 Ultra 5G 512GB, Kártyafüggetlen, 1 Év Garanciával
- Thermalright Aqua Elite 360 V3
- LG 55B4 - 55" OLED - 4K 120Hz 1ms - NVIDIA G-Sync - FreeSync Premium - HDMI 2.1 - PS5 és Xbox Ready
- HIBÁTLAN iPhone 14 128GB Midnight -1 ÉV GARANCIA - Kártyafüggetlen, MS3240
Állásajánlatok
Cég: PCMENTOR SZERVIZ KFT.
Város: Budapest
Cég: Laptopszaki Kft.
Város: Budapest