Új hozzászólás Aktív témák

• #51656 Mutt senior tag andreas49 #51645

  Új Válasz 2023-10-28 15:14:10 #51656

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz andreas49 #51645 üzenetére

  Szia,

  Kaptál már megoldást, én is mutatok egyet amellyel a M365-ben található újabb függvényeket (LAMBDA, LET, BYCOL) szeretném megismertetni.

  Röviden pár szó róluk:
  1. LAMBDA: ezzel saját függvényt lehet létrehozni, amivel a számításokat lehet egyszerúsíteni.
  2. LET: itt változókat lehet létrehozni amik segítenek a számításokban anélkül hogy segédoszlopot kellene használni
  3. BYCOL és BYROW: függvényeket lehet futtatni tömbökön amelyek oszlopban/sorban vannak.

  

  Lépések:
  1. A névkezelőben létrehoztam három saját függvényt a LAMBDA függvény segítségével.
  

  pontadott képlete =LAMBDA(x;HAHIBA(--INDEX(SZÖVEGFELOSZTÁS(x;;"–");1);""))
  pontkapott képlete =LAMBDA(x;HAHIBA(--INDEX(SZÖVEGFELOSZTÁS(x;;"–");2);""))
  nyertszett pedig =LAMBDA(x;SZUM(HA(HAHIBA(BYCOL(x;pontadott)-BYCOL(x;pontkapott);0)>0;1;0)))

  Az első kettő a 6-2-es inputból (a függvényben x) 6-ot és 2-et ad vissza. Használata a füzetben pl. =pontadott(K3)

  A harmadikban a BYCOL(x;pontadott) résszel elérhetjük, hogy mondjuk az J3:L3 tartomány celláiból megkapjuk az eredményt. Ha kivontjuk az adott és kapott pontokat egymásból, akkor megkapjuk hogy az adott szettet kinyerte meg. Van ott még hibakezelés, hogy az üres cellák ne okozzanak gondot.

  2. A fenti függvények segítségével az R3 képlete:
  =SZUM(BYCOL(G3:O3;pontadott))&"-"&SZUM(BYCOL(G3:O3;pontkapott))

  A Q3 képlete:
  =LET(win;nyertszett(G3:O3);
  total;DARAB2(G3:O3);
  win&"-"&total-win)

  Itt a "win" nevű változóban tároljuk a nyert szettek számát. A "total" az összes játszottat adja meg, az eredményt pedig az utolsó soradja meg.

  A P3 képlete:
  =LET(win;ELŐJEL(nyertszett(G3:I3))+ELŐJEL(nyertszett(J3:L3))+ELŐJEL(nyertszett(M3:O3));
  total;KEREK.FEL(DARAB2(G3:O3)/3;0);
  win&"-"&total-win)

  Itt annyi változás van, hogy a 3-as szettekből kiderítjük kinyerte meg a gémet.

  üdv

• #51650 Fire/SOUL/CD félisten andreas49 #51645

  Új Válasz 2023-10-28 09:34:23 #51650

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fire/SOUL/CD

  félisten

  válasz andreas49 #51645 üzenetére

  L3 képlete (lefelé másolható)
  =INT(BAL(M3;1)/(DARABHATÖBB(C3:K3;"<>Fire")/3-1)) & "–" & INT(JOBB(M3;1)/(DARABHATÖBB(C3:K3;"<>Fire")/3-1))

  M3 képlete (lefelé másolható)
  =SZUM(--HA(C3:K3<>"";HA(--BAL(C3:K3;1)>--JOBB(C3:K3;1);1;0);0)) & "–" & SZUM(--HA(C3:K3<>"";HA(--BAL(C3:K3;1)<--JOBB(C3:K3;1);1;0);0))

  N3 képlete (lefelé másolható)
  =SZUM(--HA(C3:K3<>"";--BAL(C3:K3;1);0)) & "–" & SZUM(--HA(C3:K3<>"";--JOBB(C3:K3;1);0))

  

• #51646 Fferi50 Topikgazda andreas49 #51645

  Új Válasz 2023-10-27 22:25:39 #51646

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fferi50

  Topikgazda

  válasz andreas49 #51645 üzenetére

  Szia!
  Nézd meg lsz. az N8 cella képletét és ennek szellemében folytasd.
  Üdv.

Új hozzászólás Aktív témák