Új hozzászólás Aktív témák

• #39889 Mutt senior tag kvoaksz #39884

  Új Válasz 2019-01-03 21:13:38 #39889

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz kvoaksz #39884 üzenetére

  Szia,

  Ha feltételezzük, hogy szám után mindig szóközzel elválasztva van az előtag jele akkor az alábbi lépések segítenek:

  1. Az első szóközig lévő szöveget (az alapszámot) az alábbi képlet megadja
  BAL(A2;SZÖVEG.TALÁL(" ";A2))

  1b. Ha magyar Exceled van, akkor pl. a 0.7-ben lévő tizedesponttal gondban lesz, de egy cserével megoldható ez. HELYETTE(BAL(A2;SZÖVEG.TALÁL(" ";A2));".";",")

  1c. Ha van a számban ezres elválasztó is (pl. 1,620), akkor pedig két cserét javaslok.
  HELYETTE(HELYETTE(BAL(A2;SZÖVEG.TALÁL(" ";A2));",";"");".";",")

  2. Opcionális lépés. Ha lehet más szabványos előtag is, vagyis nem csak "k" lehet, akkor kell ez a segédtábla, ami megadja hogy az alapszámot mennyivel kell majd szorozni. Nekem ez a segédtábla z F:G oszlopban van.

  3a. Ha csak "k" lehet a szövegben, akkor a végső képlet ennyi (az első lépésben kapott számot szorozzuk 1000-el és a végére csapjuk a "users" szöveget).
  =BAL(A2;SZÖVEG.TALÁL(" ";A2)*1000&" users"

  3b. Ha más előtag is lehet a szám után, akkor előbb ki kell keresni az előtagot és utána ahhoz megkeresni a szorzót.
  Az előtag az első szóköz utáni 2 karakter lehet (a deka-nak 2 karakteres a jelölése).
  KIMETSZ(KÖZÉP(A2;SZÖVEG.TALÁL(" ";A2);3)))

  Ezek után ehhez kell megkeresnünk a szorzót, ami egy FKERES/VLOOKUP lenne, csak az a gond hogy itt számít a kisbetű/nagybetű is a mega-milli, peta-pico stb miatt. Tömbfüggvénnyel tudjuk megoldani a helyes keresést, ha SZORZATÖSSZEG-be tesszük akkor nem kell CSE. .
  SZORZATÖSSZEG(AZONOS($F$2:$F$22;KIMETSZ(KÖZÉP(A2;SZÖVEG.TALÁL(" ";A2);3)))*$G$2:$G$22)
  Már csak össze kell rakni a fent említett részeket:
  =BAL(A2;SZÖVEG.TALÁL(" ";A2))*SZORZATÖSSZEG(AZONOS($F$2:$F$22;KIMETSZ(KÖZÉP(A2;SZÖVEG.TALÁL(" ";A2);3)))*$G$2:$G$22)&" users"

  üdv

• #39886 föccer nagyúr kvoaksz #39884

  Új Válasz 2019-01-03 20:27:57 #39886

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  föccer

  nagyúr

  válasz kvoaksz #39884 üzenetére

  ha a " k users" fix, akkor olvasd ki szövegként

  BAL(A1;HOSSZ(A1)-8)

  függvénnyel. Ezt kell beágyazni az ÉRTÉK() függvénybe, ami a szöveget számmá alakítja és ezt be kell szoroznod 1000-el.

  Így a függvényed az alábbi lesz:

  =ÉRTÉK(BAL(A1;HOSSZ(A1)-8))*1000

Új hozzászólás Aktív témák