Új hozzászólás Aktív témák

• #39909 Mutt senior tag patesz #39907

  Új Válasz 2019-01-05 00:23:25 #39909

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz patesz #39907 üzenetére

  Szia,

  Ahogy írod az igazi nehézség, hogy mindig csak egy adott halmazon (tartományon) belül kell megtalaláni az utolsó előfordulást. Tudnunk kell, hogy egy választott sor előtt melyik az utolsó üres sor és utána melyik az első üres sor.

  A G2-es cellába ezt a képletet írd be, hogy meg tudd hogy melyik az a sor ahonnan a tartomány kezdődik (eredményt csak akkor fog kiírni ha az A-oszlopban ott a "D:" kulcsszó):
  =HA(A2="D:";ÖSSZESÍT(14;6;SOR($A$2:A2)/($A$2:A2="");2)+1;"")

  A képlet lényege, hogy mindig a 2-es sortól indulva az aktuális sorig (figyeld az abszolút és relatív hivatkozásokat) megnézi, hogy hol vannak üres értékek az A-oszlopban és abból visszaadja a második legnagyobb értéket. Azért kell a második legnagyobb, mert a "D:"-sorok előtt van egy üres sor és ez lesz a legnagyobb érték, de ez még a minket érdekelt tartomány része, így eggyel korábbi üres sor kell (a második legnagyobb szám).

  A tartomány vége is hasonló módszerrel jön ki, de itt a legkisebb számot fogjuk keresni az aktuális sortól lefelé indulva. A H2-es cella képlete:
  =HA(A2="D:";ÖSSZESÍT(15;6;SOR(A2:$A$1000)/(A2:$A$1000="");1)-3;"")
  Itt éltem azzal hogy 1000-sornál nincs több adatod, de ha lenne akkor írd át!

  A képleteket húzd le az oszlopokban, hogy minden "D:" sorra megkeresse a helyes értékeket.

  Ezek után az E2 cellának a képlete:
  =HA(A2="D:";KERES(2;1/(INDIREKT("A"&G2&":A"&H2)="Motor1:");INDIREKT("D"&G2&":D"&H2));"")

  Az F2-nek pedig:
  =HA(A2="D:";KERES(2;1/(INDIREKT("A"&G2&":A"&H2)="Motor2:");INDIREKT("D"&G2&":D"&H2));"")

  Itt az általad is használt KERES megoldást használjuk, de az INDIREKT függvénnyel előállítjuk mindig azt a tartományt amelyben keresni kell a "Motor1:" és "Motor2:" kulcsszavakat.

  üdv

Új hozzászólás Aktív témák