Új hozzászólás Aktív témák

• #39483 Mutt senior tag escsé #39476

  Új Válasz 2018-10-30 00:50:46 #39483

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz escsé #39476 üzenetére

  Szia,

  Nem kell a hiperhivatkozásba az aktuális fájl név.
  A lenti képlet a fájlban az Elszámolás lap A1-es cellájára ugrik.

  =HIPERHIVATKOZÁS("#Elszámolás!A1";"Klikk ide")

  Ha szükséged van automatikusan a fájlban található munkalapok listájára, akkor egy régi függvény tud segíteni aminek az angol neve GET.WORKBOOK, magyarul pedig MUNKAFÜZETET.VESZ.

  Azonban ezt a mostani Excel-ekbe nem tudod a megszokott módon bevinni. Hozz létre a Képletek -> Névkezelőben egy új változót, pl. Lapnevek amelynek ez a képlete:
  =MUNKAFÜZETET.VESZ(1)

  

  Innentől a Lapnevek változóban mindig bent lesz az akutális füzet lapjainak neve a fájlnévvel együtt, vhogy így:
  [Művdok2.xlsx]T
  [Művdok2.xlsx]Elszámolás
  [Művdok2.xlsx]Számolólap
  [Művdok2.xlsx]Jegyzet
  [Művdok2.xlsx]SzabJegy
  [Művdok2.xlsx]KLTV Segédlet

  Ha neked csak a lapnevek kellenek, akkor egy kicsit hosszabb függvény kell a fenti változóba, aminek a képlete:
  =CSERE(MUNKAFÜZETET.VESZ(1);1;SZÖVEG.KERES("]";MUNKAFÜZETET.VESZ(1));"")

  Ahhoz hogy a fenti függvény listáját egy legördülő menübe lehessen tenni sajnos kell még 2 lépés:
  1. Vhova ki kell íratni az értékeket, ez lehet egy rejtett munkalap/oszlop.
  A képlet: =INDEX(Lapnevek;SOR())
  Húzd le a képletet jó sokat, hogy ne csak a mostani lapok de az esetleges jövőbeli lapnevek kiférjenek.

  Az én példámban a D1:D15-ös tartományba van a fenti képlet.
  

  2. Ha esetleg ABC sorrendbe akarod rendezni a listádat, akkor kell 2 segédoszlop még.
  E-ben a képlet ennyi: =DARABTELI(D:D;"<="&D1)
  Vagy ha nem akarod hogy a listádban a "T" munkalap választható legyen, akkor ez:
  =HA(D1<>"T";DARABTELI(D:D;"<="&D1);HIÁNYZIK())
  F-ben pedig ez: =INDEX(D:D;HOL.VAN(SOR();E:E;0))
  

  3. A névkezelőbe kell megint egy képlet, ami egy dinamikus tartományt csinál a kapott listából. Én most a rendezett listát adom meg neki vagyis az F1-es cellát, mert onnan indul a rendezett lista.
  A képlet ez esetben: =ELTOLÁS(T!$F$1;;;DARAB2(Lapnevek))

  

  4. B1-es cellában adatérvényesítésben megadod a 3-as lépésben létrehozott nevet (nálam Lapok)
  5. A1-be pedig kerül a hiperhivatkozás képlete
  =HIPERHIVATKOZÁS("#"&B1&"!A1";"Klikk ide")

  üdv

• #39477 Delila_1 veterán escsé #39476

  Új Válasz 2018-10-29 18:13:30 #39477

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Delila_1

  veterán

  válasz escsé #39476 üzenetére

  Csatolok egy füzetet.

  A füzet nevét meg kell adnod, nincs kibúvó.

Új hozzászólás Aktív témák