-
Fototrend
Fototrend
Új hozzászólás Aktív témák
-
pirit28
csendes tag
Jóó napot az uraknak, illetve hölgyeknek..
Ismét egy általam nem teljesíthető feladattal állok szemben ,amiben a segítséget kérném attól aki tudja a megfelelő választ.
2002-2003-as excel-t használok.
Van egy túlórás file-om sheet1 névre hallgatva.
Ebben a táblában,az első oszlopban sorszám ill. a második oszlopban nevek vannak.A 3. oszlopban meg a nevekhez tartozó műszak,...A ill. B műszak.
Szeretném ebből a táblából egy másik táblába kigyűjteni a neveket akik A műszakosak.
Kiindulni az if függvényből indultam el ,úgy hogy megnéztem az illető A műszakos-e vagy B.ezt az R és S oszlopban rögzítettem.
ezt követően a "csoportos a" fülben megpróbáltam a kicsi függvénnyel a sheet1 R oszlopában levő sorszámokat kiirattatni. =SMALL(Sheet1!$R$3:$R$82;1) "minden sorban +1"
A problémám az az hogyha elfogynak a nevek akkor #num hibaüzenet fogad,amit szeretnél eltüntetni valahogyan, de nem tudom hogyan.
Ha esetleg lenne egy egyszerűbb megoldás akkor az is megfelelne.
Mellékelek a sheet1-ről egy képet hátha többet segítek vele.
A választ, válaszokat előre is köszönöm.
-
Delila_1
veterán
Szívesen.
-
the radish
senior tag
-
Delila_1
veterán
-
the radish
senior tag
-
RJan
csendes tag
Sziasztok
szükségem lenne egy kis segítségre.
Csináltam egy "adatbázist", ahol vezetnénk kollégámmal a munkáinkat.
Négy lap van, az első az összesítő, ahol csak az időszak a változó...
Többi három lapon a munkanemek vannak. 1lap 1munkanem.
1lapon adott hónap (pl:2013_09) felmérést készítő és feldolgozó neve szerepel.
Az összesítő lapon szeretném kimutatni, h tárgyhóban ki mennyi felmérést és feldolgozást készített munkanemenként.
Lásd itt:
Íme az xlsx: http://rghost.net/private/49020327/b7bd71a18d0cf812f3e9328a87e3af25
Hiába próbálom az időszak váltásával a nevek számát kimutatni, csak egy időpontot szerepeltet és a továbbiaknál a neveket nem adja össze.
(Excel2010-ben dolgozunk.)
Segítségeteket előre is köszönöm szépen! :-) -
Delila_1
veterán
-
the radish
senior tag
-
the radish
senior tag
-
the radish
senior tag
-
81lendo$
csendes tag
Szuper valami hasonlóra gondoltam.
Pár férdésem még lenne, ha lehet.
- Ugye én nem formon, hanem Munkalapon csináltam, de elvileg ott is működik ez a megoldás?
- Ilyenkor amikor konkrét cellát viszel át egy másik fájlba, akkor fomátuma is átmegy. (pl.: pénznem [Forint], [Euro])?
- El tudnád küldeni, a kódját, az "ExportList" gombnak?
Előre is köszönöm a segítségedet!Üdv: Gábor
-
terencehIII
tag
-
Sprite75
tag
Nekem ez magas mint malacnak a zsiráfvályú.
Beraktam az M8 ba majd másoltam lefelé. Valami hiba lehet benne mert a márciushoz a M10-be nem ír semmit, viszont az utána következő hónapokat jól számolja.Közben Delila_1 -től kaptam egy ilyet privátban és ez jól működik.
M8
=HAHIBA(HA(DARABTELI(G:G;J8)>1;INDEX(D:G;HOL.VAN(J8;G:G;1);1)-K2;INDEX(D:G;HOL.VAN(J8;G:G;0);1)-INDEX(D:G;HOL.VAN(J7;G:G);1));"")
M9-től pedig
=HAHIBA(HA(DARABTELI(G:G;J9)>1;INDEX(D:G;HOL.VAN(J9;G:G;1);1)-INDEX(D:G;HOL.VAN(J8;G:G;1);1);INDEX(D:G;HOL.VAN(J9;G:G;0);1)-INDEX(D:G;HOL.VAN(J8;G:G);1));"")
A kettő közül egyiknek a működését sem értem teljesen de azért a segítséget köszönöm.
-
Caipi
tag
-
Sprite75
tag
Bonyolítás
{=HA(MAX(HA($G:$G=J14;$D:$D))=0;0;MAX(HA($G:$G=J14;$D:$D))-(M8+M9+M10+M11+M13+M12+$K$2))}
Ha a D oszlop vizsgálatának eredménye 0 mert nincs abban a hónapban tankolás akkor az adott hónap cellaértéke 0 egyébként pedig elvégzi az előbbiekben leírtakat.
Kicsit hosszú a képlet de működik -
Sprite75
tag
Valami megoldásfélét találtam, bár nem teljesen jó:
{=MAX(HA($G:$G=J14;$D:$D))-(M8+M9+M10+M11+M13+M12+$K$2)}A havi legnagyobb km-ra állásból kivonja ez előző havi értékeket minusz az előző évi záró km-óra állást.
Ez majdnem jó megoldás akkor ha van minden hónapban tankolás, de pl ennél az autónál is a februárnál minusz érték jönne ki ha a semmiből kivonja a januári futott km-ert. Ja és még azoknál a hónapoknál is hülyeséget számol ami még hátra van az évből. (8,9,10,11,12 hó)Szóval finomítani kellene a dolgon, vagy ha valakinek teljesen más ötlete van azt is szívesen fogadom
-
Sprite75
tag
Sziasztok
A következő lenne a gondom amivel nem boldogulok.Az M8 tól kezdődően lefelé ki kellene számoltatnom a havi futott Km-eket.
Összesen kb 30 járműről lenne szó és mindegyiknek így néz ki a munkalapja.
Valahogyan a hónapok száma alapján kellene az adott hónap utolsó tankolási Km-ét kivonni az előző hónap utolsó tankolási Km-éből. Csakhogy a havi tankolások darabszám, vagyis az egy hónaphoz tartozó sorok száma mindig változó, ahogy a képen is látszik.
Ennél az autónál pl a 7. havi futott km a D19-D16, a 6. havi km D16-D14, az 5. havi D14-D9 stb.Az átlagfogyasztás átlagha, a tankolt mennyiség szumha függvénnyel { =SZUMHA($G:$G;J8;$E:$E) } van megcsinálva. De ezzel a futott Km-es dologgal nem boldogulok.
Előre is köszi a szegítséget
-
terencehIII
tag
-
81lendo$
csendes tag
Sziasztok!
Van egy Excel-es problémám.
kezdés
első gomb megynyomását követve: a munkalapokat(sheets) felsorolja Listboxba
kijelölöm ki kellene.
és jönne a következő gomb...
Abban kellene segíteni azt leprogramozni.
Ezeket kell elvégeznie ennek a gombnak:
-egy új Excel file-ba ki kéne írni a Listboxban kijelölt munkalap neveket.
-és a nevek mellé (az új Workbook-ba) kellene még 3 cella adatait beírni arról a munkalapról amit kijelöltünk.
($E$2 és $K$27 és $K$28)Minden segítségnek örülök!
-
Pá
addikt
Sziasztok!
Excel 2003-at használunk a munkahelyemen és van két hotkey kombináció, amik nélkül már el sem tudnám képzelni a munkámat.
ALT + T + G --> goal seek
ALT + E + S --> paste specialTényleg nagyon gyakran használom ezeket. Gyakran van, hogy kb 2 perces időtartam alatt akár 20-30x, szóval gyakorlatilag folyamatosan.
A gond az, hogy a cég most fog váltani office 2010-re, ahol ha jól tudom ezek a kombinációk nem, vagy másképp működnek. Kérdésem, hogy lehet megoldani, hogy ezeket tudjam továbbra is használni excelben? Sajnos a gyári hotkey nem az igazi, 3 gombot is kell nyomni hozzá és annyira nem is esik kézre. Akár makró vagy külső script is jöhet, bármilyen megodlás érdekel.
-
Mutt
senior tag
Hello,
Én néztem be, mivel jól írtad le a kérést.
Az eredeti probléma megoldásához az INDEX függvény kell, amelynek a képlete INDEX(tartomány;kívánt sor száma).
Röviden ezek a képletek működnek 2007 vagy újabb Excelben:
A1-be:
=HAHIBA(INDEX(VÁLASZT(ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))+1;E:E;F:F;G:G);DARABHATÖBB(B$1:B1;B1;C$1:C1;C1)+2);"")B1-be:
=HAHIBA(INDEX($E$1:$G$1;ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))+1);"")C1-be:
=HAHIBA(INDEX($E$2:$G$2;ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))+1);"")Felraktam mindkét változtatot ide.
Hosszabban:
Az INDEX-nél nem a tartománnyal van gond igazán, hanem hogy mindig a szükséges sort adja vissza a tartományból. Itt tehát ennek a képlete a kulcs, hiszen a példádon is látható hogy először 1-től 6-ig kell egy sorszámot visszadni, majd után 1 és 3 és végül 1 és 5 között kell nekünk egy szám.Na erre a problémára ezt a képletet alkottam:
ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))Hozzáteszem, hogy természetesen van egyszerűbb változat is (HA függvények egymásba ágyazása), de annak bővíthetősége nehézkes.
A fenti képlet valójában 3x ugyanaz, nézzük egy példán:
ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))A függvény 3 értéket adhat vissza (-1;0;1) attól függően, hogy az éppen vizsgált sor száma (SOR függvény) az E:F tartományban lévő számokat tartalmazó cellák számánál több-e vagy kevesebb vagy egyenlő.
Konkrétan: ha az 5-ös sorban vagyunk, akkor 0-t fogunk kapni (=(5-1)/9), ami azt jelenti hogy az E:F oszlopokból elég választanunk cellát, mivel abban 9 van de nekünk ebből a 9-ből csak az 5 kell.
Ha a 14-es sorban vagyunk akkor pedig 1 lesz, az érték ami azt jelenti hogy nem az E:F oszlopokban van a keresett cella.A 3 db előjeles képlet csak a DARAB függvény paraméterében változik, az elsőben csak az E-oszlopokat nézzük, a másodikban már az E:F oszlopokat és a harmadikban már az E:G oszlopokat. Mindegyik rész 0-t vagy 1-et fog visszadni a fentiek szerint, de példánál maradva az első 6 sorra 0-t kapunk, 7-9-es sorokra 1-et, 10-14-es sorokra 2-öt, felette pedig 3-at.
Ezzel a függvénnyel a neheze már meg is van, de nézzük meg a többit.
Kezdem a B-oszlophoz tartozóval, mert ez az egyszerűbb.
Itt semmi más nem kell mint az E1:G1 tartományból kiírni vagy az első vagy a második vagy a harmadik értéket. A kulcs függvényünk pont erre lett kifejlesztve, így a képlet gyorsan meg is van:=INDEX($E$1:$G$1;ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))+1)
A C-oszlophoz ugyanez a logika kell csak ott E2:G2 tartományból kell kivenni az értéket, a képlet csak ebben változik.
Az A-oszlop ezek után már könnyedebb dolog lesz, de itt az a gond hogy eleinte E-oszlopból kell érték, majd F-ből és később G-ből. Itt az a megoldásom, hogy a VÁLASZT függvényt használjuk. Amelynek a szintaxisa: VÁLASZT(index szám;érték1;érték2.....).
Egy példán keresztül: VÁLASZT(2;"Férfi";"Nő";"Ismeretlen") eredménye "Nő" lesz mivel a második értéket kértük vissza a függvénytől.
A kulcs függvényünk pont egy sorszámot ad vissza - valójában egyet hozzá kell adnom, mert a tömb nem a nulladik hanem az első elemmel indul -, vagyis először E:E oszlop kell nekünk, majd F
és végül G:G. Ezek alapján a
VÁLASZT(ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))+1;E:E;F:F;G:G)
attól függően, hogy melyik sorban vagyunk E:E; F vagy G:G-t fog visszadni, amit az INDEX függvényben azonnal fel is tudunk használni.Az INDEX-nek azonban kell egy sorszám hogy hanyadik értéket kell a bemeneti tartományból visszadni. Erre kell egy újabb képlet. Itt a DARABHATÖBB-et használtam (Excel 2007 alatt SZORZATÖSSZEG segít).
Egyszerűen megszámolom az aktuális sorban hogy mellette a B és C-oszlopban szereplő értékek hányszor szerepeltek. A példára visszatérve pl. az első sorban az "a" és a "b" először szerepel, így E-oszlopból az első szám kell, a 4-ik sorban pedig már 4x szerepel így 4. szám kell az E-oszlopból.
A képlet így néz ki: DARABHATÖBB(B$1:B1;B1;C$1:C1;C1)
Itt fontos, hogy mindegyik esetben a tartomány első fele fixen van rögzítve a második pedig fut!Megis vagyunk mert tudjuk a tartományt és hogy hanyadikelem - itt kettőt hozzáadtam mert az első kettőt figyelmen kívül kell hagynunk - kell belőle. A képlet vagyis ez lesz:
INDEX(VÁLASZT(ELŐJEL(INT((SOR()-1)/DARAB($E:$E)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$F)))+ELŐJEL(INT((SOR()-1)/DARAB($E:$G)))+1;E:E;F:F;G:G);DARABHATÖBB(B$1:B1;B1;C$1:C1;C1)+2)Ezzel vége is, persze egy kis HAHIBA függvénnyel kozmetikáztam.
üdv.
-
Mutt
senior tag
Szia,
Nem jó képletet használsz, FKERES-el nem fog menni.
H3-ban ez a képlet legyen (csak 100 sort néz a képlet):
=SZORZATÖSSZEG(--($B$3:$B$100=F3);--($C$3:$C$100=G3);$D$3:$D$100)Vagy ez a CSE függvény:
{=INDEX($D$3:$D$100;HOL.VAN(F3&G3;$B$3:$B$100&$C$3:$C$100;0))}Vagy simán KERES-el:
=KERES(2;1/($B$3:$B$100=F3)/($C$3:$C$100=G3);$D$3:$D$100)
üdv.
-
Mutt
senior tag
Hello,
A lenti példára ezt a képletet tudom javasolni:
=HAHIBA(INDEX($A$1:$A$14;ÖSSZESÍT(15;6;SOR($B$1:$B$14)/(($B$1:$B$14=E$1)*($C$1:$C$14=E$2));SOROK($E$3:$E3)));"")
Az alábbi elven megy:
A képlet magja a ($B$1:$B$14=E$1)*($C$1:$C$14=E$2) rész, amely a B és C-oszlopokban lévő értékeket hasonlítja össze E1 és E2-ben lévő fix értékkel, és IGAZ vagy HAMIS értékeket add vissza ott ahol vagy van vagy nincs találat. Ha logikai változókat szorzunk össze, akkor pedig 1 és 0 lesz az érték Excelben. "a" és "b" értékre keresve tehát ezt kapjuk vissza: {1;1;1;1;1;1;0;0;0;0;0;0;0;0}
Ezek alapján tudjuk hogy mely esetekben vannak találatok, most már csak a helyük kérdéses. Ehhez jön a képbe a SOR($B$1:$B$14) rész, ez ugye ilyet ad vissza alapból: {1;2;3;4;5;6;7;8;9;10;11;12;13;14}
Ha ezt elosztjuk azzal az eredménnyel, amellyet korábban megkaptunk - amely megmondja hogy hol van a feltételeknek megfelelő egyezés - akkor kapunk egy olyan halmazt amelyben számok (1-el való osztás eredményeként) és hibák (0-val való osztás) lesznek. A SOR($B$1:$B$14)/(($B$1:$B$14=E$1)*($C$1:$C$14=E$2)) eredménye ez lesz: {1;2;3;4;5;6;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!;#ZÉRÓOSZTÓ!}Most már tudjuk, hogy melyik sorban vannak a nekünk szükséges értékek már csak sorban ki kell venni őket. Erre a KICSI(halmaz;hanyadik elem) függvény az ideális, de az csak akkor műkődik ha a halmaz nem tartalmaz hibát, nekünk pedig van egy csomó #ZÉRŐOSZTÓ! hibánk benne így ez nem járható (CSE-vel megoldható lenne). Az ÖSSZESÍT egy olyan függvény, amely képes "meghívni" egyéb függvényeket és kezeli a hibákat is. Az ÖSSZESÍT(15;6;halmaz;hanyadik elem) ugyanaz mint a KICSI(halmaz; hanyadik elem) és közben kezeli a hibákat (az első paraméter a 15-ös jelenti a KICSI-t, a második pedig hibakezelést).
Már csak azt kell megadnunk, hogy sorban az első, második, harmadik stb. elemet adja vissza a képlet.
Ilyet sokféleképpen lehet előállítani, én gyakran ezt használom: SOROK(induló cella fixen;futó cella).
Példánkban: SOROK($E$3:$E3), ez 1-et fog visszaadni, de ha lemásoljuk akkor már SOROK($E$3:$E4) lesz belőle és 2-es lesz az értéke.Ezek alapján az ÖSSZESÍT képlet teljesen így néz ki: ÖSSZESÍT(15;6;SOR($B$1:$B$14)/(($B$1:$B$14=E$1)*($C$1:$C$14=E$2));SOROK($E$3:$E3))) és az eredménye 1-es lesz mivel pont az első találat kell nekünk, amely az első sorban van.
Meg van a sorszám már csak ki kell iratni, ehhez az INDEX(tömb;sorszám) képletet lehet használni.
A végén egy HAHIBA függvénybe zárva az egészet eltüntethetűk az esetleges hibák.üdv.
-
alfa20
senior tag
köszi, de sajnos nem sikerül össze hoznom,
Van ugye két táblázatom:
Az elsőből kellene az adatokat összekeresni a másodikba, úgy ahogy a példa táblában is van,
csak persze az lenne jó ha nem kellene az első táblázatban az "A" oszlopot beszúrni és egy egyedi azonosítót létrehozni. -
kopogo
tag
-
terencehIII
tag
-
kopogo
tag
-
terencehIII
tag
-
dudikpal
senior tag
Igaz, így 1xűbb
A zöld oszlopokba akartam kategóriánként kikeresni azokat a sorokat, ahol a cikkszámok vannak, a kék oszlopokba ezeket a sorszámokat indirekttel bevinni, így megkapom a cikkszámot, ahogyan az első kategóriaoszlopban látszik is.De már azt is kezdem kétségbe vonni hogy egyáltalán jól kezdtem e neki az egésznek...
-
Gandalf80
csendes tag
Szia!
A súgót érdemes elolvasni, mert abban megtalálod a választ. A 9-es szám a "SZUM"-t jelöli, azaz összead.
Lásd! http://office.microsoft.com/hu-hu/excel-help/reszosszeg-HP005209288.aspxFÜGGV_SZÁM
(A REJTETT ÉRTÉKEK BEFOGLALÁSA) FÜGGV_SZÁM
(A REJTETT ÉRTÉKEK FIGYELMEN KÍVÜL HAGYÁSA) FÜGGVÉNY
1 101 ÁTLAG
2 102 DARAB
3 103 DARAB2
4 104 MAX
5 105 MIN
6 106 SZORZAT
7 107 SZÓRÁS
8 108 SZÓRÁSP
9 109 SZUM
10 110 VAR
11 111 VARPRemélem ez segített
-
dudikpal
senior tag
De dinnye vagyok, nem is az a gondom, azt már megoldottam
A keresés lefut A1:A324.ig, eredmények megvannak.
A valódi gondom az, hogy az A oszlop itt még nem ér véget, csak innentől új kategóriába mennek az adatok, a másik kategória keresési tartománya A324:A428. Ezt az értéket nem veszi be a Hol.van, hanem az előző kategória eredményeit adja ki újra.Az első kateg képlete: ÖSSZEFŰZ($H$1;HOL.VAN($H$2;INDIREKT(V6):INDIREKT(W2);0)+HELYETTE(V6;"A";"")+1)
a másodiké:
ÖSSZEFŰZ($H$1;HOL.VAN($H$2;INDIREKT(W6):INDIREKT(X2);0)+HELYETTE(W6;"A";"")+1)tehát csak jobbra másoltam, mégis az első kateg eredményei jönnek ki megint.
Sztem az indirektet nem jól használom itt, olyan mintha figyelembe se venné, vagy nem tudom...Ötlet vki?
-
dudikpal
senior tag
Sziasztok!
2 napja szenvedek már, és nem bírok rájönni a megoldásra:
- a hol.van-nal megkeresek A oszlopban egy adott szöveget, ennek kell ui a sorszáma.
Ezt x-szer kell ismételnem, ami ismert szám.
Ugye az oszlop tetejétől indul az első érték keresés, viszont a második keresés az első keresés eredmény sorától tartana az oszlop aljáig. A következő keresés intervalluma is ismert(kivonom a teljes sorszámból az előző keresés eredményét).
A gondom az, hogy ezt az intervallumot nem tudom hogy a csudába tudom bevinni a hol.van fvbe.A teljes keresési tartomány A1:A324.
Az első találat A12ben van, ezt indirektelem B1be. Most A13-A324ig kéne keresnem, de ezt a tartományt nem tudom betenni a hol.van-ba egy számított cellából úgy, hogy abban a tartományban keressen.Nem tudom elég érthetően írtam e le...?
-
moklys1
aktív tag
Ja és ne hozza át a rejtett sorokat az új lapra.
Mert ha úgy jelölöm, hogy bal oldalt egérrel az excel sorszámozást jelölöm ki akkor áthozza a rejtett cellákat is.Egy megoldást találta méghozzá a ctrl lenyomva tartva és soronként egyesével sorokat jelölgetve sikerül. De ez nem jó mert vagy 1000 sor van
-
Mutt
senior tag
Hello,
Ha a számok csak 1000 és 1 millió közötiek, akkor ez a számformátum megteszi:
[$$-409]#\,##0Viszont ha más számokkal is kell dolgozni, akkor ez nem lesz jó.
Megoldás lehet a Windows területi beállításának módosítása vagy Excelben a File->Beállítások->Speciális részben átállítani a tizedes és ezres elválasztókat.
Ezek után a pénzügyi formátumot kell használnod.
üdv
-
Mutt
senior tag
Hello,
...kimutatásban hogy tudom azt kiíratni, hogy az adott oszlopban, hány különböző érték van?...
Excel 2013-ban a Kimutatásban ha be van kapcsolva az Adatmodel opció, akkor lehet egyedi értékeket számoltatni (count unique records).
Korábbi verziókban pedig a táblázatba kell felvenned egy új oszlopot és benne a DARABTELI függvényt használni.
Mutatom egy példán:
Itt a városok ismétlődnek, de ha tudni akarom hogy hány van, akkor D2-be kell ez:
=HA(DARABTELI($A$2:A2;A2)=1;1;"")Ha lehúzod, akkor amikor először találja meg a várost akkor egy 1-est ír ki, minden más esetben üresen hagyja a mezőt. A függvény azt nézi, hogy addig a sorig hányszor szerepel a kérdéses város.
A második sorig (fejléccel együtt számolom) még csak egyszer lesz Budapest, de a harmadik sorban már 2x így ott már mivel duplikáció nem ír ki egyest a függvény.A végén pedig már csak az egyeseket kell összeadni a kimutatásban.
üdv.
és végül G:G. Ezek alapján a
Új hozzászólás Aktív témák
- Ráműthető a Linux PlayStation 5-re, de csak egy boot erejéig
- gban: Ingyen kellene, de tegnapra
- Autós kamerák
- Eladhatatlannak ítélt CPU-k eladásával javult az Intel node-ok kihozatala
- Gitáros topic
- PROHARDVER! feedback: bugok, problémák, ötletek
- Nos igen, ilyen is lehet egy notebook…
- Milyen légkondit a lakásba?
- Milyen billentyűzetet vegyek?
- Fujifilm X
- További aktív témák...
- Számlás!Steam,EA,Epic és egyébb játékok Pc-re vagy XBox!
- Eladó jogtiszta, Windows 11/10, Office 2019/2021/2024, Fizikai és Digitális licencek, Számlával.
- Kaspersky, BitDefender, Avast és egyéb vírusírtó licencek a legolcsóbban, egyenesen a gyártóktól!
- Játékkulcsok ! : PC Steam, EA App, Ubisoft, Windows és egyéb játékok
- MS SQL Server 2016, 2017, 2019
- Eladó egy Huawei GT3 okos óra Dobozzal tőltővel
- Kezdő Gamer PC-Számítógép! Csere-Beszámítás! I5 7500 / GTX 1650 / 16GB DDR4 / 128SSD + 500HDD
- szinteÚJ Dell Pro 14 Ultra 7 255U 16GB DDR5 1TB AI PC FHD+ 1 év garancia
- Honor X5c Plus 64GB, Kártyafüggetlen, 1 Év Garanciával
- Kuriózum: Ozark Trail (amerikai) fejlámpa 600 lumen
Állásajánlatok
Cég: Laptopműhely Bt.
Város: Budapest